Para consultar recursos semánticos, acceda al Virtuoso SPARQL Endpoint Page puesta a disposición por régimen. Verá una pantalla donde puede ingresar una consulta para especificar usando el Lenguaje SPARQL

Una vez escrita la consulta, puede seleccionar en qué formato devolver los resultados. Varias opciones son posibles incluyendo HTML, CSV, JSON, y varias serializaciones RDF como RDF/Turtle, RDF/XML, y N-Triples.
Al hacer clic en el botón «Ejecutar consulta», puede ejecutar la consulta para obtener los resultados que está buscando.
Para cancelar todo lo que escribió y eligió como resultado, puede usar el botón Restablecer.

A continuación se presentan algunos ejemplos de consultas sobre recursos semánticos de esquema en lenguaje natural. Cada consulta corresponde a una consulta SPARQL que puede ser ejecutada por Virtuoso como se describió anteriormente.

• ¿Qué municipios italianos, con su código belfiore, del archivo histórico son válidos hasta la fecha?

  PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
  PREFIX clv: <https://w3id.org/italia/onto/CLV/>
  PREFIX ti: <https://w3id.org/italia/onto/TI/>
  PREFIX l0: <https://w3id.org/italia/onto/l0/>
  SELECT ?s ?ID ?idCadastral ?name ?starttime ?endTime
  WHERE {?s a skos:Concept ;
  skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/cities> ;
  skos:notation ?ID ;
  skos:prefLabel ?name ;
  clv:hasSOValidity/ti:endTime ?endTime ;
  clv:hasSOValidity/ti:startTime ?starttime ;
  ?identifier a clv:Identifier ;
  clv:identifierType ?idType ;
  l0:identifier ?idCadastral .
  FILTER (str(?endTime)="9999-12-31")
  FILTER (str(?idType) = "Codice Catastale")
  FILTER (lang(?idType) = "it")
  }

• ¿En qué recurso semántico se define el concepto de «servicio público» y cuál es su definición?

  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  PREFIX owl: <http://www.w3.org/2002/07/owl#>
  PREFIX dct: <http://purl.org/dc/terms/>
  SELECT ?URIResource ?titleResource ?URIConcept ?label ?definition
  where {
  ?URIConcept rdfs:isDefinedBy ?URIResource ;
  rdfs:label ?label ;
  rdfs:comment ?definition .
  ?URIResource dct:title ?titleResource .
  FILTER ((str(?label)="Servizio Pubblico"))
  FILTER (lang(?label) = 'it')
  FILTER (lang(?definition) = 'it')
  FILTER (lang(?titleResource) = 'it')
  }

• ¿Cuáles son las licencias que caen bajo el tipo de licencia abierta?

  PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
  PREFIX clv: <https://w3id.org/italia/onto/CLV/>
  SELECT ?s ?ID ?name ?nameOpen
  WHERE {?s a skos:Concept ;
  skos:inScheme <https://w3id.org/italia/controlled-vocabulary/licences> ;
  clv:hasRankOrder "3" ;
  skos:notation ?ID ;
  skos:prefLabel ?name ;
  skos:broader*/skos:prefLabel ?nameOpen .
  FILTER (str(?nameOpen)="Licenza Aperta")
  FILTER (lang(?nameOpen) = 'it')
  FILTER (lang(?name) = 'it')
  }

• ¿Cuáles son las provincias italianas válidas hasta la fecha y a qué región pertenecen?

  PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
  PREFIX clv: <https://w3id.org/italia/onto/CLV/>
  SELECT ?s ?province ?name ?IDISTATProv ?IDISTATReg ?nameRegion
  WHERE {
  ?s a skos:Concept ;
  skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/provinces> ;
  skos:notation ?IDISTATProv ;
  skos:prefLabel ?name ;
  clv:acronym ?province ;
  skos:broader ?region .
  ?region a skos:Concept ;
  skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/regions> ;
  skos:notation ?IDISTATReg ;
  skos:prefLabel ?nameRegion .
  }

  ¿Qué son las ciudades metropolitanas?

  PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
  PREFIX clv: <https://w3id.org/italia/onto/CLV/>
  PREFIX l0: <https://w3id.org/italia/onto/l0/>
  SELECT ?s ?province ?name ?IDISTATProv ?IDISTATReg ?nameRegion ?identifier ?idMetropolitanCode
  WHERE {
  ?s a skos:Concept ;
  skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/provinces> ;
  skos:notation ?IDISTATProv ;
  skos:prefLabel ?name ;
  clv:acronym ?province ;
  clv:hasIdentifier ?identifier ;
  skos:broader ?region .
  ?identifier a clv:Identifier ;
  clv:identifierType ?idType ;
  l0:identifier ?idMetropolitanCode .
  ?region a skos:Concept ;
  skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/regions> ;
  skos:notation ?IDISTATReg ;
  skos:prefLabel ?nameRegion .
  FILTER (str(?idType) = "Codice Città Metropolitana")
  FILTER (lang(?idType) = 'it')
  }

• ¿En qué recurso semántico se define el «número cívico»?

  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  PREFIX owl: <http://www.w3.org/2002/07/owl#>
  PREFIX dct: <http://purl.org/dc/terms/>
  SELECT ?URIResource ?titleResource ?URIConcept ?label
  where {
  ?URIConcept rdfs:isDefinedBy ?URIResource ;
  rdfs:label ?label .
  ?URIResource dct:title ?titleResource .
  FILTER ((str(?label)="Numero Civico"))
  FILTER (lang(?label) = 'it')
  FILTER (lang(?titleResource) = 'it')
  }