Requête des ressources sémantiques

Pour interroger des ressources sémantiques, accédez au Virtuoso SPARQL Endpoint Page mis à disposition par le régime. Vous verrez un écran où vous pouvez entrer une requête à spécifier à l'aide du Langue SPARQL

Image descriptive de l'écran qui vous permet d'écrire une requête SPARQL

Une fois la requête écrite, vous pouvez sélectionner dans quel format retourner les résultats. Plusieurs options sont possibles, notamment HTML, CSV, JSON et plusieurs sérialisations RDF telles que RDF/Turtle, RDF/XML et N-Triples.
En cliquant sur le bouton «Exécuter la requête», vous pouvez exécuter la requête pour obtenir les résultats que vous recherchez.
Pour annuler tout ce que vous avez tapé et choisi en conséquence, vous pouvez utiliser le bouton Réinitialiser.

Image descriptive des options concernant le format de résultat de la requête, l'exécution de la requête et l'annulation de la requête

Note :

Pour faciliter la définition de la requête, il est suggéré de parcourir les différentes ressources sémantiques actuellement publiées sur le schéma via le Web. Les ressources sont navigables grâce à des logiciels mis à disposition tels que LODE et LodView. Pour ce faire, utilisez simplement l'URI des ressources elles-mêmes dans votre navigateur.

Exemples de requêtes SPARQL

Voici quelques exemples de requêtes sur les ressources sémantiques de schéma en langage naturel. Chaque requête correspond à une requête SPARQL qui peut être exécutée par Virtuoso comme décrit ci-dessus.

  • Quelles communes italiennes, avec leur code belfiore, des archives historiques sont valables à ce jour? 
    PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
PREFIX ti: <https://w3id.org/italia/onto/TI/>
PREFIX l0: <https://w3id.org/italia/onto/l0/>
SELECT ?s ?ID ?idCadastral ?name ?starttime ?endTime
WHERE {?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/cities> ;
skos:notation ?ID ;
skos:prefLabel ?name ;
clv:hasSOValidity/ti:endTime ?endTime ;
clv:hasSOValidity/ti:startTime ?starttime ;
?identifier a clv:Identifier ;
clv:identifierType ?idType ;
l0:identifier ?idCadastral .
FILTER (str(?endTime)="9999-12-31")
FILTER (str(?idType) = "Codice Catastale")
FILTER (lang(?idType) = "it")
}
  • Dans quelle ressource sémantique la notion de «service public» est-elle définie et quelle est sa définition? 
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dct: <http://purl.org/dc/terms/>
SELECT ?URIResource ?titleResource ?URIConcept ?label ?definition
where {
?URIConcept rdfs:isDefinedBy ?URIResource ;
rdfs:label ?label ;
rdfs:comment ?definition .
?URIResource dct:title ?titleResource .
FILTER ((str(?label)="Servizio Pubblico"))
FILTER (lang(?label) = 'it')
FILTER (lang(?definition) = 'it')
FILTER (lang(?titleResource) = 'it')
}
  • Quelles sont les licences qui relèvent du type de licence ouverte? 
    PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
SELECT ?s ?ID ?name ?nameOpen
WHERE {?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/licences> ;
clv:hasRankOrder "3" ;
skos:notation ?ID ;
skos:prefLabel ?name ;
skos:broader*/skos:prefLabel ?nameOpen .
FILTER (str(?nameOpen)="Licenza Aperta")
FILTER (lang(?nameOpen) = 'it')
FILTER (lang(?name) = 'it')
}
  • Quelles sont les provinces italiennes valables à ce jour et à quelle région appartiennent-elles? 
    PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
SELECT ?s ?province ?name ?IDISTATProv ?IDISTATReg ?nameRegion
WHERE {
?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/provinces> ;
skos:notation ?IDISTATProv ;
skos:prefLabel ?name ;
clv:acronym ?province ;
skos:broader ?region .
?region a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/regions> ;
skos:notation ?IDISTATReg ;
skos:prefLabel ?nameRegion .
}

    Que sont les villes métropolitaines?

    PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
PREFIX l0: <https://w3id.org/italia/onto/l0/>
SELECT ?s ?province ?name ?IDISTATProv ?IDISTATReg ?nameRegion ?identifier ?idMetropolitanCode
WHERE {
?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/provinces> ;
skos:notation ?IDISTATProv ;
skos:prefLabel ?name ;
clv:acronym ?province ;
clv:hasIdentifier ?identifier ;
skos:broader ?region .
?identifier a clv:Identifier ;
clv:identifierType ?idType ;
l0:identifier ?idMetropolitanCode .
?region a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/regions> ;
skos:notation ?IDISTATReg ;
skos:prefLabel ?nameRegion .
FILTER (str(?idType) = "Codice Città Metropolitana")
FILTER (lang(?idType) = 'it')
}
  • Dans quelle ressource sémantique le «nombre civique» est-il défini? 
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dct: <http://purl.org/dc/terms/>
SELECT ?URIResource ?titleResource ?URIConcept ?label
where {
?URIConcept rdfs:isDefinedBy ?URIResource ;
rdfs:label ?label .
?URIResource dct:title ?titleResource .
FILTER ((str(?label)="Numero Civico"))
FILTER (lang(?label) = 'it')
FILTER (lang(?titleResource) = 'it')
}