Recursos semânticos de consulta

Para consultar os recursos semânticos, acesse o Página de ponto final do Virtuoso SPARQL disponibilizadas pelo sistema. Verá um ecrã onde pode introduzir uma consulta para especificar utilizando o Língua SPARQL

Imagem descritiva do ecrã que lhe permite escrever uma consulta SPARQL

Uma vez escrita a consulta, pode selecionar em que formato devolver os resultados. Várias opções são possíveis, incluindo HTML, CSV, JSON e várias serializações RDF, como RDF/Turtle, RDF/XML e N-Triples.
Clicando no botão «Executar consulta», pode executar a consulta para obter os resultados que procura.
Para cancelar tudo o que digitou e escolheu como resultado, pode utilizar o botão Repor.

Imagem descritiva das opções relativas ao formato do resultado da consulta, à execução da consulta e ao cancelamento da consulta

Nota:

Para facilitar a definição da consulta, sugere-se navegar pelos vários recursos semânticos atualmente publicados no esquema através da Web. Os recursos são navegáveis através de softwares disponibilizados, como o LODE e o LodView. Para fazer isso, basta usar o URI dos próprios recursos no seu navegador.

Exemplos de consultas SPARQL

Seguem-se alguns exemplos de consultas sobre recursos semânticos de esquemas em linguagem natural. Cada consulta corresponde a uma consulta SPARQL que pode ser executada por Virtuoso como descrito acima.

  • Que municípios italianos, com o seu código belfiore, do arquivo histórico são válidos até à data? 
    PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
PREFIX ti: <https://w3id.org/italia/onto/TI/>
PREFIX l0: <https://w3id.org/italia/onto/l0/>
SELECT ?s ?ID ?idCadastral ?name ?starttime ?endTime
WHERE {?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/cities> ;
skos:notation ?ID ;
skos:prefLabel ?name ;
clv:hasSOValidity/ti:endTime ?endTime ;
clv:hasSOValidity/ti:startTime ?starttime ;
?identifier a clv:Identifier ;
clv:identifierType ?idType ;
l0:identifier ?idCadastral .
FILTER (str(?endTime)="9999-12-31")
FILTER (str(?idType) = "Codice Catastale")
FILTER (lang(?idType) = "it")
}
  • Em que recurso semântico é definido o conceito de «serviço público» e qual é a sua definição? 
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dct: <http://purl.org/dc/terms/>
SELECT ?URIResource ?titleResource ?URIConcept ?label ?definition
where {
?URIConcept rdfs:isDefinedBy ?URIResource ;
rdfs:label ?label ;
rdfs:comment ?definition .
?URIResource dct:title ?titleResource .
FILTER ((str(?label)="Servizio Pubblico"))
FILTER (lang(?label) = 'it')
FILTER (lang(?definition) = 'it')
FILTER (lang(?titleResource) = 'it')
}
  • Quais são as licenças que se enquadram no tipo de licença aberta? 
    PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
SELECT ?s ?ID ?name ?nameOpen
WHERE {?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/licences> ;
clv:hasRankOrder "3" ;
skos:notation ?ID ;
skos:prefLabel ?name ;
skos:broader*/skos:prefLabel ?nameOpen .
FILTER (str(?nameOpen)="Licenza Aperta")
FILTER (lang(?nameOpen) = 'it')
FILTER (lang(?name) = 'it')
}
  • Quais são as províncias italianas válidas até à data e a que região pertencem? 
    PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
SELECT ?s ?province ?name ?IDISTATProv ?IDISTATReg ?nameRegion
WHERE {
?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/provinces> ;
skos:notation ?IDISTATProv ;
skos:prefLabel ?name ;
clv:acronym ?province ;
skos:broader ?region .
?region a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/regions> ;
skos:notation ?IDISTATReg ;
skos:prefLabel ?nameRegion .
}

    O que são as cidades metropolitanas?

    PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
PREFIX l0: <https://w3id.org/italia/onto/l0/>
SELECT ?s ?province ?name ?IDISTATProv ?IDISTATReg ?nameRegion ?identifier ?idMetropolitanCode
WHERE {
?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/provinces> ;
skos:notation ?IDISTATProv ;
skos:prefLabel ?name ;
clv:acronym ?province ;
clv:hasIdentifier ?identifier ;
skos:broader ?region .
?identifier a clv:Identifier ;
clv:identifierType ?idType ;
l0:identifier ?idMetropolitanCode .
?region a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/regions> ;
skos:notation ?IDISTATReg ;
skos:prefLabel ?nameRegion .
FILTER (str(?idType) = "Codice Città Metropolitana")
FILTER (lang(?idType) = 'it')
}
  • Em que recurso semântico é definido o “Número Cívico”? 
    PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dct: <http://purl.org/dc/terms/>
SELECT ?URIResource ?titleResource ?URIConcept ?label
where {
?URIConcept rdfs:isDefinedBy ?URIResource ;
rdfs:label ?label .
?URIResource dct:title ?titleResource .
FILTER ((str(?label)="Numero Civico"))
FILTER (lang(?label) = 'it')
FILTER (lang(?titleResource) = 'it')
}