Per interrogare le risorse semantiche, accedi alla <a href="https://www.schema.gov.it/sparql">pagina dello SPARQL endpoint Virtuoso</a> messo a disposizione da schema. Ti comparirà una schermata dove è possibile inserire una query da specificare utilizzando il <a href="https://www.w3.org/TR/sparql11-query/">linguaggio SPARQL</a>
<img class="alignnone wp-image-736" src="https://schema.gov.it/wp-content/uploads/2025/12/SPARQL-endpoint.png" alt="Immagine descrittiva della schermata che consente di scrivere una query SPARQL" width="721" height="236" />
Una volta scritta la query è possibile selezionare in quale formato restituire i risultati. Sono possibili diverse opzioni tra cui HTML, CSV, JSON, e diverse serializzazioni RDF quali RDF/Turtle, RDF/XML e N-Triples.
Cliccando sul bottone “Execute Query” si può eseguire la query per ottenere i risultati cercati.
Per annullare tutto quello digitato e scelto come risultato, è possibile utilizzare il bottone Reset.
<img class="alignnone wp-image-737" src="https://schema.gov.it/wp-content/uploads/2025/12/SPARQL-opzioni-riguardanti-i-risultati.jpg" alt="Immagine descrittiva delle opzioni riguardanti il formato dei risultati della query, l’esecuzione della query e relativo annullamento " width="719" height="70" />
Per facilitare la definizione della query, si suggerisce di navigare via Web le varie risorse semantiche attualmente pubblicate su schema. Le risorse sono navigabili mediante software messi a disposizione come LODE e LodView. Per farlo è sufficiente utilizzare nel browser l’URI delle risorse stesse.
Di seguito si riportano in linguaggio naturale alcuni esempi di interrogazioni sulle risorse semantiche di schema. Ciascuna interrogazione corrisponde a una query SPARQL che può essere eseguita da Virtuoso come prima descritto.
Di seguito si riportano in linguaggio naturale alcuni esempi di interrogazioni sulle risorse semantiche di schema. Ciascuna interrogazione corrisponde a una query SPARQL che può essere eseguita da Virtuoso come prima descritto.
<ul>
<li><strong>Quali sono i comuni italiani, con relativo codice belfiore, dell’archivio storico ad essere validi ad oggi?</strong>
<pre><code>PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
PREFIX ti: <https://w3id.org/italia/onto/TI/>
PREFIX l0: <https://w3id.org/italia/onto/l0/>
SELECT ?s ?ID ?idCadastral ?name ?starttime ?endTime
WHERE {?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/cities> ;
skos:notation ?ID ;
skos:prefLabel ?name ;
clv:hasSOValidity/ti:endTime ?endTime ;
clv:hasSOValidity/ti:startTime ?starttime ;
?identifier a clv:Identifier ;
clv:identifierType ?idType ;
l0:identifier ?idCadastral .
FILTER (str(?endTime)="9999-12-31")
FILTER (str(?idType) = "Codice Catastale")
FILTER (lang(?idType) = "it")
}</code></pre>
</li>
<li><strong>In quale risorsa semantica è definito il concetto di “Servizio Pubblico” e qual è la sua definizione?</strong>
<pre><code>PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dct: <http://purl.org/dc/terms/>
SELECT ?URIResource ?titleResource ?URIConcept ?label ?definition
where {
?URIConcept rdfs:isDefinedBy ?URIResource ;
rdfs:label ?label ;
rdfs:comment ?definition .
?URIResource dct:title ?titleResource .
FILTER ((str(?label)="Servizio Pubblico"))
FILTER (lang(?label) = 'it')
FILTER (lang(?definition) = 'it')
FILTER (lang(?titleResource) = 'it')
}</code></pre>
</li>
<li><strong>Quali sono le licenze che ricadono sotto la tipologia di licenza aperta?</strong>
<pre><code>PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
SELECT ?s ?ID ?name ?nameOpen
WHERE {?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/licences> ;
clv:hasRankOrder "3" ;
skos:notation ?ID ;
skos:prefLabel ?name ;
skos:broader*/skos:prefLabel ?nameOpen .
FILTER (str(?nameOpen)="Licenza Aperta")
FILTER (lang(?nameOpen) = 'it')
FILTER (lang(?name) = 'it')
}</code></pre>
</li>
<li><strong>Quali sono le province italiane valide ad oggi e a quale regione appartengono?</strong>
<pre><code>PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
SELECT ?s ?province ?name ?IDISTATProv ?IDISTATReg ?nameRegion
WHERE {
?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/provinces> ;
skos:notation ?IDISTATProv ;
skos:prefLabel ?name ;
clv:acronym ?province ;
skos:broader ?region .
?region a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/regions> ;
skos:notation ?IDISTATReg ;
skos:prefLabel ?nameRegion .
}</code></pre>
<strong>Quali sono invece le città metropolitane?</strong>
<pre><code>PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX clv: <https://w3id.org/italia/onto/CLV/>
PREFIX l0: <https://w3id.org/italia/onto/l0/>
SELECT ?s ?province ?name ?IDISTATProv ?IDISTATReg ?nameRegion ?identifier ?idMetropolitanCode
WHERE {
?s a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/provinces> ;
skos:notation ?IDISTATProv ;
skos:prefLabel ?name ;
clv:acronym ?province ;
clv:hasIdentifier ?identifier ;
skos:broader ?region .
?identifier a clv:Identifier ;
clv:identifierType ?idType ;
l0:identifier ?idMetropolitanCode .
?region a skos:Concept ;
skos:inScheme <https://w3id.org/italia/controlled-vocabulary/territorial-classifications/regions> ;
skos:notation ?IDISTATReg ;
skos:prefLabel ?nameRegion .
FILTER (str(?idType) = "Codice Città Metropolitana")
FILTER (lang(?idType) = 'it')
}</code></pre>
</li>
<li><strong>In quale risorsa semantica è definito il “Numero Civico”?</strong>
<pre><code>PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dct: <http://purl.org/dc/terms/>
SELECT ?URIResource ?titleResource ?URIConcept ?label
where {
?URIConcept rdfs:isDefinedBy ?URIResource ;
rdfs:label ?label .
?URIResource dct:title ?titleResource .
FILTER ((str(?label)="Numero Civico"))
FILTER (lang(?label) = 'it')
FILTER (lang(?titleResource) = 'it')
}</code></pre>
</li>
</ul>